Rule 1.2: Support aggregation of results at macro locations

Add a new module/library for identifying the macro that generated
an element as the primary location, and use it for Rule 1.2 to
avoid overreporting.

Author: lcartey

c/misra/src/rules/RULE-1-2/LanguageExtensionsShouldNotBeUsed.ql

@@ -13,8 +13,9 @@
 
 import cpp
 import codingstandards.c.misra
+import codingstandards.cpp.AlertReporting
 import codingstandards.c.Extensions
 
 from CCompilerExtension e
 where not isExcluded(e, Language3Package::languageExtensionsShouldNotBeUsedQuery())
-select e, e.getMessage()
+select MacroUnwrapper<CCompilerExtension>::unwrapElement(e), e.getMessage()

c/misra/test/rules/RULE-1-2/LanguageExtensionsShouldNotBeUsed.expected

@@ -48,3 +48,4 @@
 | test.c:376:3:376:26 | call to __sync_lock_test_and_set_4 | Call to builtin function '__sync_lock_test_and_set_4' is a compiler extension and is not portable to other compilers. |
 | test.c:377:3:377:21 | call to __sync_lock_release_4 | Call to builtin function '__sync_lock_release_4' is a compiler extension and is not portable to other compilers. |
 | test.c:405:3:405:18 | call to __builtin_alloca | Call to builtin function '__builtin_alloca' is a compiler extension and is not portable to other compilers. |
+| test.c:409:1:411:8 | #define BUILTIN __builtin_alloca( 0) | Call to builtin function '__builtin_alloca' is a compiler extension and is not portable to other compilers. |

c/misra/test/rules/RULE-1-2/test.c

@@ -404,4 +404,10 @@ void gf47() { // NON_COMPLIANT in versions < C11.
 void gf48() {
   __builtin_alloca(
       0); // NON_COMPLIANT (all __builtin functions are non-compliant.)
-}
+}
+
+#define BUILTIN                                                                \
+  __builtin_alloca(                                                            \
+      0) // NON_COMPLIANT (all __builtin functions are non-compliant.)
+
+void gf49() { BUILTIN; }

cpp/common/src/codingstandards/cpp/AlertReporting.qll

@@ -0,0 +1,41 @@
+/**
+ * Provides a library for managing how alerts are reported.
+ */
+
+import cpp
+
+signature class ResultType extends Element;
+
+/**
+ * A module for unwrapping results that occur in macro expansions.
+ */
+module MacroUnwrapper<ResultType ResultElement> {
+  /**
+   * Gets a macro invocation that applies to the result element.
+   */
+  private MacroInvocation getAMacroInvocation(ResultElement re) {
+    result.getAnExpandedElement() = re
+  }
+
+  /**
+   * Gets the primary macro that generated the result element.
+   */
+  Macro getPrimaryMacro(ResultElement re) {
+    exists(MacroInvocation mi |
+      mi = getAMacroInvocation(re) and
+      // No other more specific macro that expands to element
+      not exists(MacroInvocation otherMi |
+        otherMi = getAMacroInvocation(re) and otherMi.getParentInvocation() = mi
+      ) and
+      result = mi.getMacro()
+    )
+  }
+
+  /**
+   * If a result element is expanded from a macro invocation, then return the "primary" macro that
+   * generated the element, otherwise return the element itself.
+   */
+  Element unwrapElement(ResultElement re) {
+    if exists(getPrimaryMacro(re)) then result = getPrimaryMacro(re) else result = re
+  }
+}